In 10 Lines or Less

Sep 26

Written by:
9/26/2009 8:57 AM 

Logging to a DotNetNuke (DNN) site with either username or email is not supported out of the box. Here is a simple way to do this. First, make sure the membership provider in your Web.config is set to require unique emails when creating accounts. You'll find this on this section of your Web.config:

<add name="AspNetSqlMembershipProvider" type="System.Web.Security.SqlMembershipProvider" connectionStringName="SiteSqlServer" enablePasswordRetrieval="true" enablePasswordReset="true" requiresQuestionAndAnswer="false" minRequiredPasswordLength="7" minRequiredNonalphanumericCharacters="0" requiresUniqueEmail="true" passwordFormat="Encrypted" applicationName="DotNetNuke" description="Stores and retrieves membership data from the local Microsoft SQL Server database" />

Next, locate the following file: Website\DesktopModules\AuthenticationServices\DNN\Login.ascx.vb and replace the the cmdLogin_Click event handler with the following (see below how to change the caption for the username to something like 'Username or Email'): 

        Private Sub cmdLogin_Click(ByVal sender As Object, ByVal e As EventArgs) Handles cmdLogin.Click

            If (UseCaptcha And ctlCaptcha.IsValid) OrElse (Not UseCaptcha) Then
                Dim loginStatus As UserLoginStatus = UserLoginStatus.LOGIN_FAILURE
                Dim objUser As Entities.Users.UserInfo = Nothing
                Dim authenticated As Boolean = Null.NullBoolean
                Dim message As String = Null.NullString
                Dim objUsers As ArrayList = Nothing
                Dim strUsername As String = txtUsername.Text
                Dim intTotalRecords As Integer = -1

                If DotNetNuke.Services.Mail.Mail.IsValidEmailAddress(strUsername, PortalId) _
                    And MembershipProvider.Instance.RequiresUniqueEmail Then

                    objUsers = DotNetNuke.Entities.Users.UserController.GetUsersByEmail(PortalId, strUsername, 0, 1, intTotalRecords)
                    If intTotalRecords > 0 Then
                        objUser = objUsers(0)
                        strUsername = objUser.Username
                    Else
                        strUsername = txtUsername.Text
                    End If

                End If

                objUser = Entities.Users.UserController.ValidateUser(PortalId, strUsername, txtPassword.Text, "DNN", txtVerification.Text, PortalSettings.PortalName, IPAddress, loginStatus)

                If loginStatus = UserLoginStatus.LOGIN_USERNOTAPPROVED Then
                    'Check if its the first time logging in to a verified site
                    If PortalSettings.UserRegistration = PortalRegistrationType.VerifiedRegistration Then
                        If Not rowVerification1.Visible Then
                            'Display Verification Rows so User can enter verification code
                            rowVerification1.Visible = True
                            rowVerification2.Visible = True
                            message = "EnterCode"
                        Else
                            If txtVerification.Text <> "" Then
                                message = "InvalidCode"
                            Else
                                message = "EnterCode"
                            End If
                        End If
                    Else
                        message = "UserNotAuthorized"
                    End If
                Else
                    authenticated = (loginStatus <> UserLoginStatus.LOGIN_FAILURE)
                End If

                'Raise UserAuthenticated Event
                Dim eventArgs As UserAuthenticatedEventArgs = New UserAuthenticatedEventArgs(objUser, txtUsername.Text, loginStatus, "DNN")
                eventArgs.Authenticated = authenticated
                eventArgs.Message = message
                OnUserAuthenticated(eventArgs)
            End If

        End Sub

NOTE: Once setup you can use DNN language settings to change the caption of the username field to say 'Username or Email' by going to 'Admin' > 'Languages' > 'Shared Resources', locate the 'Username.Text' entry, modify to say something like 'Username or Email' and save.